install nautilus-elementary on Gentoo ?

Message

ikshaar · Post by **ikshaar** » Thu Feb 04, 2010 9:12 pm

There is a patched nautilus version call nautilus-elementary
https://launchpad.net/nautilus-elementary

The theme that made me decide to try it is this one:
http://www.webupd8.org/2010/02/beautifu ... theme.html

Anyone knows a way to install that on Gentoo if there is any ? there is instructions for Ubuntu but that's all I can find.

hotice · Post by **hotice** » Thu Feb 04, 2010 9:30 pm

You can get it from BZR:

bzr branch lp:nautilus-elementary

Nautilus Elementary page: https://launchpad.net/nautilus-elementary

ikshaar · Post by **ikshaar** » Tue Feb 09, 2010 8:58 pm

Thanks. I was able to get it that way.

I was not able to get it to work correctly however.

Rexilion · Post by **Rexilion** » Wed Feb 10, 2010 9:07 am

ikshaar wrote:Thanks. I was able to get it that way.

I was not able to get it to work correctly however.

Where did it fail? You could also just

ebuild /path/to/gentoo/nautilus.ebuild prepare

Patch the nautilus inside /var/tmp/portage/

ebuild /path/to/gentoo/nautilus.ebuild compile

and if that works ok:

ebuild /path/to/gentoo/nautilus.ebuild merge

ikshaar · Post by **ikshaar** » Thu Feb 18, 2010 10:24 pm

The problem was not to build it per se. But it would not start correctly. Killing the old nautilus to force it to restart would leave me with no nautilus at all, no desktop, and some cryptic error message. Nautilus processes was hanging and I could not do much.

As this is not supported software, it does not have ebuild, I did not expect anyone else to have it installed under Gentoo, so I did not bother to post about it and gave up.. i needed my system back

96140 · Post by **96140** » Mon Aug 23, 2010 2:04 pm

tomk · Post by **tomk** » Mon Aug 23, 2010 2:08 pm

Moved from Desktop Environments to Unsupported Software as it's not in the Portage tree.

omidxo · Post by **omidxo** » Tue Aug 24, 2010 12:31 pm

nautilus-elementary-2.30 works well.
nautilus-2.30.1-r1.ebuild :

Code: Select all

# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="2"
GCONF_DEBUG="no"

inherit eutils gnome2 virtualx autotools bzr

EBZR_CACHE_DIR="nautilus-elementary-2.30"
EBZR_REPO_URI="lp:nautilus-elementary/2.30"

DESCRIPTION="A file manager for the GNOME desktop"
HOMEPAGE="http://www.gnome.org/projects/nautilus/"
SRC_URI="!elementary? ( ${SRC_URI} )"

LICENSE="GPL-2 LGPL-2 FDL-1.1"
SLOT="0"
KEYWORDS="~x86 ~amd64"
IUSE="doc elementary gnome xmp"

RDEPEND=">=dev-libs/glib-2.24.0
	>=gnome-base/gnome-desktop-2.29.91
	>=x11-libs/pango-1.1.2
	>=x11-libs/gtk+-2.20.0
	>=dev-libs/libxml2-2.4.7
	>=media-libs/libexif-0.5.12
	>=gnome-base/gconf-2.0
	dev-libs/libunique
	dev-libs/dbus-glib
	x11-libs/libXft
	x11-libs/libXrender
	xmp? ( >=media-libs/exempi-2 )"

DEPEND="${RDEPEND}
	>=dev-lang/perl-5
	sys-devel/gettext
	>=dev-util/pkgconfig-0.9
	>=dev-util/intltool-0.40.1
	doc? ( >=dev-util/gtk-doc-1.4 )"

PDEPEND="gnome? ( >=x11-themes/gnome-icon-theme-1.1.91 )
	>=gnome-base/gvfs-0.1.2"

DOCS="AUTHORS ChangeLog* HACKING MAINTAINERS NEWS README THANKS TODO"

pkg_setup() {
	G2CONF="${G2CONF}
		--disable-update-mimedb
		--disable-packagekit
		--enable-empty-view
		$(use_enable xmp)"
}

src_unpack() {
	if use elementary; then
		bzr_src_unpack
	else
		gnome2_src_unpack
	fi
}

src_prepare() {
	#epatch ${FILESDIR}/89_use_application_indicator.patch

	gtkdocize || die "gtkdocize failed"
	eautoreconf
	intltoolize -f || die "intltoolize failed"

	gnome2_src_prepare

	# FIXME: tarball generated with broken gtk-doc, revisit me.
	if use doc; then
		sed "/^TARGET_DIR/i \GTKDOC_REBASE=/usr/bin/gtkdoc-rebase" \
			-i gtk-doc.make || die "sed 1 failed"
	else
		sed "/^TARGET_DIR/i \GTKDOC_REBASE=/bin/true" \
			-i gtk-doc.make || die "sed 2 failed"
	fi

	# Fix intltoolize broken file, see upstream #577133
	sed "s:'\^\$\$lang\$\$':\^\$\$lang\$\$:g" -i po/Makefile.in.in \
		|| die "sed 3 failed"

	# Remove crazy CFLAGS
	sed 's:-DG.*DISABLE_DEPRECATED::g' -i configure.in configure \
		|| die "sed 4 failed"

	# Fix nautilus flipping-out with --no-desktop -- bug 266398
	epatch "${FILESDIR}/${PN}-2.27.4-change-reg-desktop-file-with-no-desktop.patch"

}

src_test() {
	addwrite "/root/.gnome2_private"
	unset SESSION_MANAGER
	unset ORBIT_SOCKETDIR
	unset DBUS_SESSION_BUS_ADDRESS
	Xemake check || die "Test phase failed"
}

src_install() {
	gnome2_src_install
	find "${D}" -name "*.la" -delete || die "remove of la files failed"
}

pkg_postinst() {
	gnome2_pkg_postinst

	elog "nautilus can use gstreamer to preview audio files. Just make sure"
	elog "to have the necessary plugins available to play the media type you"
	elog "want to preview"
}

The following code is for test. Requested glib-2.25.9 and gtk+-2.21.2 .
nautilus-2.31.90.ebuild :

Code: Select all

# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="2"
GCONF_DEBUG="no"

inherit eutils gnome2 virtualx autotools bzr

EBZR_CACHE_DIR="nautilus-elementary-2.31+"
EBZR_REPO_URI="lp:nautilus-elementary/2.31+"

DESCRIPTION="A file manager for the GNOME desktop"
HOMEPAGE="http://www.gnome.org/projects/nautilus/"
SRC_URI="mirror://gentoo/introspection.m4.bz2"

LICENSE="GPL-2 LGPL-2 FDL-1.1"
SLOT="0"
KEYWORDS="~x86 ~amd64"
IUSE="doc gnome xmp"

RDEPEND=">=dev-libs/glib-2.25.9
	>=gnome-base/gnome-desktop-2.29.91
	>=x11-libs/pango-1.1.2
	>=x11-libs/gtk+-2.21.2
	>=dev-libs/libxml2-2.4.7
	>=media-libs/libexif-0.5.12
	>=gnome-base/gconf-2.0
	dev-libs/libunique
	dev-libs/dbus-glib
	x11-libs/libXft
	x11-libs/libXrender
	xmp? ( >=media-libs/exempi-2 )"

DEPEND="${RDEPEND}
	>=dev-lang/perl-5
	sys-devel/gettext
	>=dev-util/pkgconfig-0.9
	>=dev-util/intltool-0.40.1
	doc? ( >=dev-util/gtk-doc-1.4 )"

PDEPEND="gnome? ( >=x11-themes/gnome-icon-theme-1.1.91 )
	>=gnome-base/gvfs-0.1.2"

DOCS="AUTHORS ChangeLog* HACKING MAINTAINERS NEWS README THANKS TODO"

pkg_setup() {
	G2CONF="${G2CONF}
		--disable-static
		--disable-introspection
		--disable-update-mimedb
		--disable-packagekit
		--enable-empty-view
		$(use_enable xmp)"
}

src_unpack() {
		bzr_src_unpack
		gnome2_src_unpack
}

src_prepare() {
	#epatch ${FILESDIR}/89_use_application_indicator.patch

 	# eautoreconf needs introspection.m4, bug #324167
	mv "${WORKDIR}"/introspection.m4 m4/

	./autogen.sh || die "autogen.sh failed"

	gnome2_src_prepare

	# FIXME: tarball generated with broken gtk-doc, revisit me.
	if use doc; then
		sed "/^TARGET_DIR/i \GTKDOC_REBASE=/usr/bin/gtkdoc-rebase" \
			-i gtk-doc.make || die "sed 1 failed"
	else
		sed "/^TARGET_DIR/i \GTKDOC_REBASE=/bin/true" \
			-i gtk-doc.make || die "sed 2 failed"
	fi

	# Fix intltoolize broken file, see upstream #577133
	sed "s:'\^\$\$lang\$\$':\^\$\$lang\$\$:g" -i po/Makefile.in.in \
		|| die "sed 3 failed"

	# Remove crazy CFLAGS
	sed 's:-DG.*DISABLE_DEPRECATED::g' -i configure.in configure \
		|| die "sed 4 failed"

	# Fix nautilus flipping-out with --no-desktop -- bug 266398
	epatch "${FILESDIR}/${PN}-2.27.4-change-reg-desktop-file-with-no-desktop.patch"

}

src_test() {
	addwrite "/root/.gnome2_private"
	unset SESSION_MANAGER
	unset ORBIT_SOCKETDIR
	unset DBUS_SESSION_BUS_ADDRESS
	Xemake check || die "Test phase failed"
}

src_install() {
	gnome2_src_install
	find "${D}" -name "*.la" -delete || die "remove of la files failed"
}

pkg_postinst() {
	gnome2_pkg_postinst

	elog "nautilus can use gstreamer to preview audio files. Just make sure"
	elog "to have the necessary plugins available to play the media type you"
	elog "want to preview"
}

namelessmatt · Post by **namelessmatt** » Tue Nov 23, 2010 10:32 am

does not compile, configure fails with message "No package 'zeitgeist-1.0' found"

Full log -- /var/tmp/portage/gnome-base/nautilus-2.31.90/temp/build.log

Rion · Post by **Rion** » Tue Nov 23, 2010 12:54 pm

namelessmatt wrote:does not compile, configure fails with message "No package 'zeitgeist-1.0' found"

Full log -- /var/tmp/portage/gnome-base/nautilus-2.31.90/temp/build.log

https://launchpad.net/nautilus-elementa ... ement/7221

omidxo · Post by **omidxo** » Wed Dec 08, 2010 1:56 am

Quick ebuild for libzeitgeist-0.2.14, requested by nautilus-elementary-2.31+

Code: Select all

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=2
inherit gnome2 eutils

DESCRIPTION="Zeitgeist Client Library"
HOMEPAGE="https://launchpad.net/libzeitgeist"
SRC_URI="http://launchpad.net/libzeitgeist/0.2/0.2.14/+download/libzeitgeist-0.2.14.tar.gz"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

RDEPEND=">=dev-libs/glib-2.15"
DEPEND="${RDEPEND}
	>=dev-util/pkgconfig-0.9"

pkg_setup() {
	G2CONF="${G2CONF}
	--enable-module=no"
}