Advice for go ebuild

[Thybolt]

I'm trying to update dev-util/hut from 0.6.0 to 0.7.0 on Guru.

As it is written in Go, the build process needs a vendor directory to build inside the sandbox.

One thing that has changed from 0.6.0 is that the vendor directory is now released by the upstream maintainer.

Source tarbal and vendor tarball are not extracted to the same directory so not merged together.

I'm trying to remedy this by specifying the src_prepare function and moving the tarball manually but the ebuild seem to fail at the src_unpack function.

Overriding the src_unpack function does nothing.

This issue seem very similar to this one https://forums.gentoo.org/viewtopic-t-1 ... endor.html but nothing helped me there.

Current error:

go mod verify
go: codeberg.org/emersion/go-scfg@v0.1.0: Get "https://proxy.golang.org/codeberg.org/e ... v0.1.0.mod": dial tcp: lookup proxy.golang.org on 100.64.0.55:53: dial udp 100.64.0.55:53: connect: network is unreachable"

Current ebuild:

Code: Select all

# Copyright 2023-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit go-module

DESCRIPTION="CLI tool for sourcehut"

HOMEPAGE="https://sr.ht/~xenrox/hut/"

SRC_URI="https://git.sr.ht/~xenrox/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
SRC_URI+=" https://git.sr.ht/~xenrox/${PN}/refs/download/v${PV}/${PN}-v${PV}-vendor.tar.xz -> ${P}-vendor.tar.xz"

S="${WORKDIR}/hut-v${PV}"

LICENSE="AGPL-3"
SLOT="0"

KEYWORDS="~amd64"

BDEPEND="app-text/scdoc"

src_prepare() {
        mv ../hut/vendor .
}

src_compile() {
        ego build
        emake doc/hut.1 completions
}

src_install() {
        dobin hut
        emake install PREFIX="${EPREFIX}/usr" DESTDIR="${D}"
}

Thank you

[salahx]

This works:

Code: Select all

# Copyright 2023-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit go-module

DESCRIPTION="CLI tool for sourcehut"

HOMEPAGE="https://sr.ht/~xenrox/hut/"

SRC_URI="https://git.sr.ht/~xenrox/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
SRC_URI+=" https://git.sr.ht/~xenrox/${PN}/refs/download/v${PV}/${PN}-v${PV}-vendor.tar.xz -> ${P}-vendor.tar.xz"

S="${WORKDIR}/hut-v${PV}"

LICENSE="AGPL-3"
SLOT="0"

KEYWORDS="~amd64"

BDEPEND="app-text/scdoc"

src_unpack() {
        default
        mv go_mod "${WORKDIR}" || die
}

src_compile() {
        ego build
        emake doc/hut.1 completions
}

src_install() {
        dobin hut
        emake install PREFIX="${EPREFIX}/usr" DESTDIR="${D}"
}

[Thybolt]

Thanks

I modified

Code: Select all

mv go_mod "${WORKDIR}" || die 

Into

Code: Select all

mv hut/vendor "${S}" || die

Have a nice day

[logrusx]

I was thinking of changing a variable but the eclass didn't provide any that make sense. However I'm not that familiar with Go.

Maybe you could get better help on IRC. Especially if the author of the eclass hangs there, but also there are many people who can give you input on your ebuild.

Best Regards,
Georgi