Gentoo Forums
Gentoo Forums
Gentoo Forums
Quick Search: in
[PALUDIS+ZSH] Completions
View unanswered posts
View posts from last 24 hours

 
Reply to topic    Gentoo Forums Forum Index French
View previous topic :: View next topic  
Author Message
Bapt
Veteran
Veteran


Joined: 14 Apr 2003
Posts: 1152
Location: Paris

PostPosted: Thu Dec 21, 2006 5:01 pm    Post subject: [PALUDIS+ZSH] Completions Reply with quote

EDIT : intégré depuis la version 0.14 de paludis use zsh-completion
UPDATE : n'utilisant pas la version svn de paludis donc les fonction de completion sont en retard par rapport au nouvelles fonctionnalité, voici donc un patch pour avoir les options apparues entre la 0.12 et la 0.14.2 : http://baptux.free.fr/_paludis-0.14.2.patch
Pour l'appliquer :
Code:

cd /usr/share/zsh/site-functions/
patch -p0 < chemin_vers_/_paludis-0.14.2.patch


Paludis fourni des fonctions de completions pour bash avec le use flash bash-completion, mais rien pour ZSH.

De plus en essayant les fonctions de completion bash, elles ne sont pas terrible, en effet toutes les options sont offertes à tous les niveaux, même si on a déjà mis des options incompatibles avec celles offertes.

J'ai donc pris mon plus beau vim et ai fait des fonctions de completions zsh pour paludis sur le même modèle que celles que j'avais déjà fait pour portage il y a longtemps.

C'est pas parfait, mais toutes les options sont dispo et je trouve le comportement/fonctionnalité plus évolué que celle pour bash.

attention au copier coller, j'ai mis une version à dl : _paludis
_paludis_packages
Procédure à suivre :
copier dans /usr/share/zsh/site_functions/_paludis_packages :
Code:
#autoload

#Author: Bapt <baptux@free.fr>
# function for paludis packages
# Usage _paludis_packages installed|available|repositories|categories|sets
local flags prepo packages categories
_paludis_packages_update_available(){
  categories=(${${(M)${(f)"$(paludis --list-categories)"}:#\* *}##\* })
  if [[ $PREFIX != */* ]];then
    _wanted cat_packages expl "category/packages" compadd -S "/" $categories
  else
  compset -P '*/'
# packages=(${${(M)${(f)"$(paludis --category ${PREFIX//\//} --list-packages)"}:#\* *}##\* })
  packages=(${${${(M)${(f)"$(paludis --category ${IPREFIX//\//} --list-packages)"}:#\* *}##\* }//$IPREFIX/})
  _wanted cat_packages expl "category/packages" compadd ${(@)packages}
  fi
}

_paludis_packages_update_installed(){
  packages=(${${(M)${(f)"$(paludis --repository installed --list-packages)"}:#\* *}##\* })

  compadd ${(@)packages}
}
_paludis_packages_update_categories(){
  packages=(${${${(M)${(f)"$(paludis --list-categories)"}:#\* *}##\* }:#*(virtual|installed)*})
  compadd ${(@)packages}
}
_paludis_packages_update_repositories(){
  packages=(${${${(M)${(f)"$(paludis --list-repositories)"}:#\* *}##\* }:#*(virtual|installed)*})
  compadd ${(@)packages}
}
_paludis_packages_update_sets(){
  packages=(${${${(M)${(f)"$(paludis --list-sets)"}:#\* *}##\* }:#*(virtual|installed)*})
  compadd ${(@)packages}
}
_paludis_packages(){
  local command="$argv[$#]" expl cachevar pkgset update_policy
  zstyle -s ":completion:*:*:$service:*" cache-policy update_policy
  if [[ -z "$update_policy" ]]; then
    zstyle ":completion:*:*:$service:*" cache-policy _paludis_cache_policy
  fi
  [[ "$command" == (installed|available|categories|repositories|sets) ]] || {
    _message "unknown command: $command"
    return
  }
  [[ "$pkgset" ==  (installed|available|categoriesrepositories|sets) ]] || {
    pkgset="$command"
  }
  expl=("${(@)argv[1,-2]}")
    _paludis_packages_update_$pkgset
}
_paludis_cache_policy () {
# rebuild if cache is more than a week old
    oldp=( "$1"(mw+1) )
    (( $#oldp )) && return 0
}

_paludis_packages "$@"


et dans /usr/share/zsh/site_functions/_paludis
Code:

#compdef paludis
_paludis () {
  local actions action_args query_args general_args deplist_args install_uninstall_args list_args lists
  actions=( --query --install -i --uninstall -u --sync -s --report --contents -k --owner -o --version -V --info -I --help -h \
  --has-version  --best-version --environnement-variable --list-repositories --list-categories --list-packages --list-sets --list-sync-protocols --list-repository-formats --list-dep-tag-categories --regenerate-installed-cache  --update-news --regenerate-installable-cache)

  query_args=(
    '(--show-deps -D)'{--show-deps,-D}"[Show dependencies]"
    '(--show-metadata -M)'{--show-metadata,-M}"[Show raw metadata]"
  )

  install_uninstall_args=(
    '(--pretend -p)'{--pretend,-p}"[Pretend only]"
    '(--preserve-world -1)'{--preserve-world,-1}"[Don t modify the world file]"
    '--no-config-protection[Disable config file protection (dangerous)]'
    '--debug-build[What to do with debug information]:Debug Build:(( none\:Discard\ debug\ information split\:Split\ debug\ information internal\:Keep\ debug\ information\ with\ binaries ))'
    '(--fetch -f)'{--fetch,-f}'[Only fetch sources; don t install anything]'
    '--show-install-reasons[Show why packages are being installed]:Verbosity:((none\:Don\ t\ show\ any\ information summary\:Show\ a\ summary full\:Show\ full\ output))'
    '--with-unused-dependencies[Also uninstall any dependencies of the target that are no longer used]'
    '--with-dependencies[Also uninstall packages that depend upon the target]'
  )
  list_args=(
    '--repository[Matches with this repository name only]:repository:_paludis_packages repositories'
    '--category[Matches with this category name only]:category:_paludis_packages category'
    '--package[Matches with this package name only]:package:_paludis_packages available'
    '--set[Matches with this package set name only]:set:_paluldis_packages set'
  )

  lists=(
    '(: -)--list-repositories[List available repositories]'
    '(: -)--list-categories[List available categories]'
    '(: -)--list-packages[List available packages]'
    '(: -)--list-sets[List available package sets]'
    '(: -)--list-sync-protocols[List available sync protocols]'
    '(: -)--list-repository-formats[List available repository formats]'
    '(: -)--list-dep-tag-categories[List known dep tag categories]'
  )
  general_args=(
    '--log-level[Specify the log level]:log level:((debug\:Show\ debug\ output qa\:Show\ QA\ messages\ and\ warnings\ only warning\:Show\ warnings\ only silent\:Suppress\ all\ log\ messages))'
    '(--no-colour --no-color)'{--no-colour,--no-color}"[Do not use colour]"
    '(--config-suffix -c)'{-c,--config-suffix}"[Config directory suffix]"
  )

  action_args=(
    "($actions)"{-q,--query}"[Query for package information]"
    "($actions)"{-i,--install}"[Install one or more packages]"
    "($actions)"{-u,--uninstall}"[Uninstall one or more packages]"
    "(: -)"{--sync,-s}"[Sync all or specified repositories]:repository:_paludis_packages repositories"
    "($actions)--uninstall-unused[Uninstall unused packages]"
    "(: -)"{--report,-r}"[Report the current state of the system]"
    "(: -)"{--contents,-k}"[Display contents of a package]:package:_paludis_packages installed"
    "(: -)"{--owner,-o}"[Display the owner of a file]:File:_files"
    "(: -)"{--version,-V}"[Display program version]"
    "(: -)"{--info,-I}"[Display program version and system information]"
    "(: -)"{--help,-h}"[Display program help]"
    "(: -)--has-version[Check whether the specified atom is installed]:package:_paludis_packages available"
    "(: -)--best-version[Display the best version of the specified atom]:package _paludis_packages available"
    "(: -)--environment-variable[Display the value of an environment variable for a particular package]:package:_paludis_packages available"
    "(: -)--configuration-variable[Display the value of a configuration variable for a particular repository]:_paludis_packages repositories"
    "(: -)--update-news[Regenerate news.unread files]"
    "(: -)--regenerate-installed-cache[Regenerate (non-metadata) cache for installed repositories]"
    "(: -)--regenerate-installable-cache[Regenerate (non-metadata) cache for installable repositories]"
  )
  deplist_args=(
    "--dl-reinstall[When to reinstall packages]:When:(never always if-use-changed)"
    "--dl-reinstall-scm[When to reinstall scm packages]:When:(never always daily weekly)"
    "--dl-upgrade[When to upgrade packages]:When:(always as-needed)"
    "--dl-installed-deps-pre[How to handle pre dependencies for installed packages]:How:(pre pre-or-post post try-post discard)"
    "--dl-installed-deps-runtime[How to handle runtime dependencies for installed packages]:How:(pre pre-or-post post try-post discard)"
    "--dl-installed-deps-post[How to handle post dependencies for installed packages]:How:(pre pre-or-post post try-post discard)"
    "--dl-uninstalled-deps-pre[How to handle pre dependencies for uninstalled packages]:How:(pre pre-or-post post try-post discard)"
    "--dl-uninstalled-deps-post[How to handle post dependencies for uninstalled packages]:How:(pre pre-or-post post try-post discard)"
    "--dl-circular[How to handle circular dependencies]:How:(error discard)"
    "--dl-fall-back[When to fall back to installed packages]:When:(as-needed-except-targets as-needed never)"
  )
  #dispatch
  if (( $words[(I)(--(uninstall)|-[[:alpha:]]#(u)[[:alpha:]]#)] )) ; then
    _arguments -s \
        $general_args[@] $deplist_args[@] $install_uninstall_args[@] \
        "*:installed package:_paludis_packages installed" && return 0
  elif (( $words[(I)--uninstall-unused] )) ; then
      _arguments -s \
        $deplist_args[@] $install_uninstall_args[@] && return 0
  elif (( $words[(I)(--(install)|-[[:alpha:]]#(i)[[:alpha:]]#)] )) ;then
    _arguments -s \
        $general_args[@] $deplist_args[@] $install_uninstall_args[@] \
      "*:available packages:_paludis_packages available" && return 0
  elif (( $words[(I)(--(query)|-[[:alpha:]]#(q)[[:alpha:]]#)] )) ;then
    _arguments -s \
        $general_args[@] $query_args[@]\
      "*:available packages:_paludis_packages available" && return 0
  elif (( $words[(I)--(repository|package|category|set)] ));then
    _arguments \
      $lists[@] && reruen 0
  else
    _arguments -s \
      $general_args[@] $deplist_args[@] $list_args[@] $lists[@] $install_uninstall_args[@] "$action_args[@]" && return 0
  fi
}
_paludis "$@"


les noms de fichiers sont importants, en revanche le répertoire dois juste être dans $fpath.

Voila.

paludis -[tab] :)

EDIT : J'allais oublié, il y a le support des overlay, car des appels à paludis sont fait pour récupérer tout : catérories, sets, répertoires, packages etc.


Last edited by Bapt on Mon Jan 08, 2007 11:25 am; edited 2 times in total
Back to top
View user's profile Send private message
truc
Advocate
Advocate


Joined: 25 Jul 2005
Posts: 3199

PostPosted: Thu Dec 21, 2006 5:40 pm    Post subject: Reply with quote

ouaaaaa, bon sérieu, faut vraiment que j'essaie zsh!!

En plus ça me ferai du bien, quelque chose de nouveau;)

Merci pour ton travail en tout cas!

As tu également fais la completion pour les outils de paludis (qualudis ...)? Non pas que j'en ai besoin, mais si tu l'as fait, ça a des chances de pouvoir integrer l'arbre officiel, non? :)

[EDIT] Sérieu ce flag ncurse pour zsh c'est pour quoi??
_________________
The End of the Internet!
Back to top
View user's profile Send private message
Bapt
Veteran
Veteran


Joined: 14 Apr 2003
Posts: 1152
Location: Paris

PostPosted: Thu Dec 21, 2006 5:57 pm    Post subject: Reply with quote

Le flag ncurses c'est pour utiliser curses-terminfo au lieu de terminfo directement, c'est pour manipuler le terminal je crois. (lecture du configure --help + google :)) J'ai toujours installé avec ncurses sans vraiment me poser de question (j'ai plein d'appli ncurses :))

EDIT: j'oublie de répondre à la question principale : non je n'ai pas encore fait qualudis, j'attends des retours d'expérience sur paludis et je passerai à qualudis dès que je serai satisfait de paludis, ensuite, je le proposerai à ciaranm.


Last edited by Bapt on Thu Dec 21, 2006 6:01 pm; edited 1 time in total
Back to top
View user's profile Send private message
TrizoLakai
Apprentice
Apprentice


Joined: 09 Jun 2006
Posts: 231
Location: Nantes (FRANCE)

PostPosted: Thu Dec 21, 2006 6:00 pm    Post subject: Reply with quote

Je vais faire mon gros lourd, mais ça ne fonctionne pas. Une fois que j'ai créé les fichier je doit rajouter qqch à ~/.zshrc ?
Back to top
View user's profile Send private message
Bapt
Veteran
Veteran


Joined: 14 Apr 2003
Posts: 1152
Location: Paris

PostPosted: Thu Dec 21, 2006 6:04 pm    Post subject: Reply with quote

TrizoLakai wrote:
Je vais faire mon gros lourd, mais ça ne fonctionne pas. Une fois que j'ai créé les fichier je doit rajouter qqch à ~/.zshrc ?

J'ai oublié :
Code:
compdef -a _paludis paludis


et si ça ne fonctionne toujours pas (vérifie eu relog), supprime ton fichier .zcompdump et relog toi, zsh va le recréer.
Back to top
View user's profile Send private message
TrizoLakai
Apprentice
Apprentice


Joined: 09 Jun 2006
Posts: 231
Location: Nantes (FRANCE)

PostPosted: Thu Dec 21, 2006 6:29 pm    Post subject: Reply with quote

Ok.

Bon j'ai ça :

Quote:
trizolakai@Athlou site-functions % paludis -
_arguments:comparguments:208: invalid argument:
_paludis:95: command not found: --log-level[Specify the log level]:log level:((debug\:Show\ debug\ output qa\:Show\ QA\ messages\ and\ warnings\ only warning\:Show\ warnings\ only silent\:Suppress\ all\ log\ messages))
Back to top
View user's profile Send private message
Marsu
Guru
Guru


Joined: 18 Jun 2003
Posts: 329
Location: Lyon

PostPosted: Thu Dec 21, 2006 6:42 pm    Post subject: Reply with quote

moi je vais jouer mon ignorant, mais c'est quoi paludis ?
_________________
qui ne tente rien n'a rien
Back to top
View user's profile Send private message
TrizoLakai
Apprentice
Apprentice


Joined: 09 Jun 2006
Posts: 231
Location: Nantes (FRANCE)

PostPosted: Thu Dec 21, 2006 6:48 pm    Post subject: Reply with quote

C'est un remplaçant à portage écris en C++

https://forums.gentoo.org/viewtopic-t-497873-highlight-paludis.html
Back to top
View user's profile Send private message
Bapt
Veteran
Veteran


Joined: 14 Apr 2003
Posts: 1152
Location: Paris

PostPosted: Thu Dec 21, 2006 6:51 pm    Post subject: Reply with quote

[quote="TrizoLakai"]Ok.

Bon j'ai ça :

Quote:
trizolakai@Athlou site-functions % paludis -
_arguments:comparguments:208: invalid argument:
_paludis:95: command not found: --log-level[Specify the log level]:log level:((debug\:Show\ debug\ output qa\:Show\ QA\ messages\ and\ warnings\ only warning\:Show\ warnings\ only silent\:Suppress\ all\ log\ messages))


Je comprends pas, moi jai ça :
Code:
-=[bapt@gallway]=(~)> paludis -
option
--best-version                              -- Display the best version of the specified atom                                                                       
--category                                  -- Matches with this category name only                                                                                 
--config-suffix                 -c          -- Config directory suffix                                                                                             
--configuration-variable                    -- Display the value of a configuration variable for a particular repository                                           
--contents                      -k          -- Display contents of a package                                                                                       
--debug-build                               -- What to do with debug information                                                                                   
--dl-circular                               -- How to handle circular dependencies                                                                                 
--dl-fall-back                              -- When to fall back to installed packages                                                                             
--dl-installed-deps-post                    -- How to handle post dependencies for installed packages                                                               
--dl-installed-deps-pre                     -- How to handle pre dependencies for installed packages                                                               
--dl-installed-deps-runtime                 -- How to handle runtime dependencies for installed packages                                                           
--dl-reinstall                              -- When to reinstall packages                                                                                           
--dl-reinstall-scm                          -- When to reinstall scm packages                                                                                       
--dl-uninstalled-deps-post                  -- How to handle post dependencies for uninstalled packages                                                             
--dl-uninstalled-deps-pre                   -- How to handle pre dependencies for uninstalled packages                                                             
--dl-upgrade                                -- When to upgrade packages                                                                                             
--environment-variable                      -- Display the value of an environment variable for a particular package                                               
--fetch                         -f          -- Only fetch sources; don t install anything                                                                           
--has-version                               -- Check whether the specified atom is installed                                                                       
--help                          -h          -- Display program help                                                                                                 
--info                          -I          -- Display program version and system information                                                                       
--install                       -i          -- Install one or more packages                                                                                         
--list-categories                           -- List available categories                                                                                           
--list-dep-tag-categories                   -- List known dep tag categories                                                                                       
--list-packages                             -- List available packages                                                                                             
--list-repositories                         -- List available repositories                                                                                         
--list-repository-formats                   -- List available repository formats                                                                                   
--list-sets                                 -- List available package sets                                                                                         
--list-sync-protocols                       -- List available sync protocols                                                                                       
--log-level                                 -- Specify the log level                                                                                               
--no-colour                     --no-color  -- Do not use colour                                                                                                   
--no-config-protection                      -- Disable config file protection (dangerous)                                                                           
--owner                         -o          -- Display the owner of a file                                                                                         
--package                                   -- Matches with this package name only                                                                                 
--preserve-world                -1          -- Don t modify the world file                                                                                         
--pretend                       -p          -- Pretend only                                                                                                         
--query                         -q          -- Query for package information                                                                                       
--regenerate-installable-cache              -- Regenerate (non-metadata) cache for installable repositories                                                         
--regenerate-installed-cache                -- Regenerate (non-metadata) cache for installed repositories                                                           
--report                        -r          -- Report the current state of the system                                                                               
--repository                                -- Matches with this repository name only                                                                               
--set                                       -- Matches with this package set name only                                                                             
--show-install-reasons                      -- Show why packages are being installed                                                                               
--sync                          -s          -- Sync all or specified repositories                                                                                   
--uninstall                     -u          -- Uninstall one or more packages                                                                                       
--uninstall-unused                          -- Uninstall unused packages                                                                                           
--update-news                               -- Regenerate news.unread files                                                                                         
--version                       -V          -- Display program version                                                                                             
--with-dependencies                         -- Also uninstall packages that depend upon the target                                                                 
--with-unused-dependencies                  -- Also uninstall any dependencies of the target that are no longer used                               
Back to top
View user's profile Send private message
Bapt
Veteran
Veteran


Joined: 14 Apr 2003
Posts: 1152
Location: Paris

PostPosted: Thu Dec 21, 2006 6:54 pm    Post subject: Reply with quote

OK je pense que j'ai trouvé, attention au copier coller, j'ai mis une version à dl : _paludis
_paludis_packages

voila
Back to top
View user's profile Send private message
TrizoLakai
Apprentice
Apprentice


Joined: 09 Jun 2006
Posts: 231
Location: Nantes (FRANCE)

PostPosted: Thu Dec 21, 2006 7:22 pm    Post subject: Reply with quote

j'ai fais a coup de wget j'ai pareil.
Back to top
View user's profile Send private message
Bapt
Veteran
Veteran


Joined: 14 Apr 2003
Posts: 1152
Location: Paris

PostPosted: Thu Dec 21, 2006 7:26 pm    Post subject: Reply with quote

TrizoLakai wrote:
j'ai fais a coup de wget j'ai pareil.

Tu t'es bien déloggué reloggé ?
Back to top
View user's profile Send private message
TrizoLakai
Apprentice
Apprentice


Joined: 09 Jun 2006
Posts: 231
Location: Nantes (FRANCE)

PostPosted: Thu Dec 21, 2006 7:34 pm    Post subject: Reply with quote

Oups :oops:

Pardon.

Ça fonctionne niquel, merci beaucoup :)
Back to top
View user's profile Send private message
Babali
Apprentice
Apprentice


Joined: 01 Jan 2004
Posts: 211
Location: France, Paris

PostPosted: Thu Dec 21, 2006 9:47 pm    Post subject: Reply with quote

Bapt, root a zsh par defaut chez toi ? J'ai pas trop encore ose touche a la conf de root en ce qui concerne le shell.
Back to top
View user's profile Send private message
Bapt
Veteran
Veteran


Joined: 14 Apr 2003
Posts: 1152
Location: Paris

PostPosted: Thu Dec 21, 2006 10:22 pm    Post subject: Reply with quote

root a zsh chez moi depuis des lustres quelque soit l'os ;) je ne me souviens pas avoir eu de problème particulier au contraire. Mes gentoo ont toujours eu root en zsh dès l'installation et ce depuis que je connais gentoo...

j'avais il y a environ 3 ans proposé un virtual/shell pour virer bah des dépendence par défaut, il fallait juste faire du bourne shell pou l'init et portage, mais ça a été refusé :(
Back to top
View user's profile Send private message
SanKuKai
Apprentice
Apprentice


Joined: 17 Feb 2006
Posts: 228
Location: Toulouse, France

PostPosted: Thu Dec 21, 2006 11:09 pm    Post subject: Reply with quote

Ah ! C'est vraiment génial ça ! :D
Grand merci pour ton boulot Bapt. :wink:
Back to top
View user's profile Send private message
Bapt
Veteran
Veteran


Joined: 14 Apr 2003
Posts: 1152
Location: Paris

PostPosted: Thu Dec 21, 2006 11:57 pm    Post subject: Reply with quote

SanKuKai wrote:
Ah ! C'est vraiment génial ça ! :D
Grand merci pour ton boulot Bapt. :wink:


de rien :) c'est pas compliqué à faire et en plus c'est super pratique et ça sert tous les jours :)

celui-ci a été beaucoup facile que celui pour portage (sur lequel y a eu pas mal d'aide) : l'expérience et paludis qui fournit tout ce qu'il faut en 2s rendent les choses plus simple ;)
Back to top
View user's profile Send private message
Bapt
Veteran
Veteran


Joined: 14 Apr 2003
Posts: 1152
Location: Paris

PostPosted: Fri Dec 22, 2006 10:02 am    Post subject: Reply with quote

Voila la completion pour adjutrix. Elle est largement à peaufiner mais elle fonctionne :
_adjutrix
Back to top
View user's profile Send private message
Bapt
Veteran
Veteran


Joined: 14 Apr 2003
Posts: 1152
Location: Paris

PostPosted: Fri Dec 22, 2006 12:18 pm    Post subject: Reply with quote

Les deux fonctions vont être rajoutées au svn de paludis :) donc devrait venir avec la prochaine version de paludis...
Back to top
View user's profile Send private message
Darkael
Veteran
Veteran


Joined: 10 Aug 2004
Posts: 1321
Location: France

PostPosted: Fri Dec 22, 2006 1:33 pm    Post subject: Reply with quote

Babali wrote:
Bapt, root a zsh par defaut chez toi ? J'ai pas trop encore ose touche a la conf de root en ce qui concerne le shell.

En même temps s'il utilise Paludis, c'est qu'il aime vivre dangeureusement...

Blague à part, j'utilise moi aussi zsh pour root depuis des années (enfin, 2 ans), ça a jamais posé de problèmes.
Back to top
View user's profile Send private message
truc
Advocate
Advocate


Joined: 25 Jul 2005
Posts: 3199

PostPosted: Sat Dec 23, 2006 6:55 pm    Post subject: Reply with quote

KarnEvil wrote:
En même temps s'il utilise Paludis, c'est qu'il aime vivre dangeureusement...


Rhoo, ce troll enorme :lol: :twisted:
_________________
The End of the Internet!
Back to top
View user's profile Send private message
Bapt
Veteran
Veteran


Joined: 14 Apr 2003
Posts: 1152
Location: Paris

PostPosted: Sun Dec 24, 2006 10:46 am    Post subject: Reply with quote

KarnEvil wrote:
En même temps s'il utilise Paludis, c'est qu'il aime vivre dangeureusement...

ou que j'aime vivre avec mon temps et les technos les plus performantes :twisted:
Back to top
View user's profile Send private message
Babali
Apprentice
Apprentice


Joined: 01 Jan 2004
Posts: 211
Location: France, Paris

PostPosted: Mon Dec 25, 2006 6:05 pm    Post subject: Reply with quote

Bapt wrote:
KarnEvil wrote:
En même temps s'il utilise Paludis, c'est qu'il aime vivre dangeureusement...

ou que j'aime vivre avec mon temps et les technos les plus performantes :twisted:

Tient d'ailleur s'en est ou l'utf-8 et zsh ? ;-)
Back to top
View user's profile Send private message
geekounet
Bodhisattva
Bodhisattva


Joined: 11 Oct 2004
Posts: 3772
Location: Wellington, Aotearoa

PostPosted: Mon Dec 25, 2006 6:08 pm    Post subject: Reply with quote

Babali wrote:
Bapt wrote:
KarnEvil wrote:
En même temps s'il utilise Paludis, c'est qu'il aime vivre dangeureusement...

ou que j'aime vivre avec mon temps et les technos les plus performantes :twisted:

Tient d'ailleur s'en est ou l'utf-8 et zsh ? ;-)

Ça marche très bien :)
Back to top
View user's profile Send private message
Bapt
Veteran
Veteran


Joined: 14 Apr 2003
Posts: 1152
Location: Paris

PostPosted: Mon Jan 08, 2007 11:27 am    Post subject: Reply with quote

Ajour dans le premier post d'un patch pour faire la mise à jour de la completion paludis vers la 0.14.2
Back to top
View user's profile Send private message
Display posts from previous:   
Reply to topic    Gentoo Forums Forum Index French All times are GMT
Page 1 of 1

 
Jump to:  
You cannot post new topics in this forum
You cannot reply to topics in this forum
You cannot edit your posts in this forum
You cannot delete your posts in this forum
You cannot vote in polls in this forum