Gentoo Forums
Gentoo Forums
Gentoo Forums
Quick Search: in
DeVeDe 1.4 ebuild
View unanswered posts
View posts from last 24 hours

 
Reply to topic    Gentoo Forums Forum Index Unsupported Software
View previous topic :: View next topic  
Author Message
count_zero
Guru
Guru


Joined: 17 May 2004
Posts: 459
Location: Little Rock, Arkansas, USA

PostPosted: Wed May 17, 2006 6:33 pm    Post subject: DeVeDe 1.4 ebuild Reply with quote

Here's a pretty neat DVD creator program that's not in portage, which does video conversion to mpeg-2 files.
http://www.rastersoft.com/programas/devede.html

I've hacked together a really ugly looking ebuild (I don't know much about making these), but it works.
Code:
# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils

DESCRIPTION="DVD Video Creator"
HOMEPAGE="http://www.rastersoft.com/programas/devede.html"
SRC_URI="http://www.rastersoft.com/descargas/devede14.tar.bz2"

LICENSE="GPL"
SLOT="0"
KEYWORDS="x86"
IUSE=""

RDEPEND=">=x11-libs/gtk+-2.4
        >=dev-lang/python
        >=dev-util/glade
        >=dev-python/pygtk
        >=media-video/mplayer
        >=media-video/dvdauthor
        >=app-cdr/cdrtools"

DEPEND="${RDEPEND}"

S=${WORKDIR}/devede

src_unpack()
{
        unpack ${A}
}

src_install() {
        cd ${S}
        mkdir -p ${D}/usr/bin/
        mkdir -p ${D}/usr/share/devede
        mkdir -p ${D}/usr/share/doc/devede
        mkdir -p ${D}/usr/share/locale/es/LC_MESSAGES
        mkdir -p ${D}/usr/share/locale/gl/LC_MESSAGES
        mkdir -p ${D}/usr/share/pixmaps
        mkdir -p ${D}/usr/share/applications
        install devede.py ${D}/usr/bin/ || die "failed to install"
        chmod 755 ${D}/usr/bin/devede.py || die "failed to install"
        install -d ${D}/usr/share/devede/ || die "failed to install"
        install -d ${D}/usr/share/doc/devede/ || die "failed to install"
        install -d ${D}/usr/share/locale/es/LC_MESSAGES || die "failed to install"
        install -d ${D}/usr/share/locale/gl/LC_MESSAGES || die "failed to install"
        install po/es.mo ${D}/usr/share/locale/es/LC_MESSAGES/devede.mo || die "failed to install"
        install po/gl.mo ${D}/usr/share/locale/gl/LC_MESSAGES/devede.mo || die "failed to install"
        install devede.glade ${D}/usr/share/devede/devede.glade || die "failed to install"
        install devede.png ${D}/usr/share/pixmaps/ || die "failed to install"
        install devede.desktop ${D}/usr/share/applications/devede.desktop || die "failed to install"
        install docs/* ${D}/usr/share/doc/devede/ || die "failed to install"
        install pixmaps/* ${D}/usr/share/devede/ || die "failed to install"
}


Feel free to suggest improvements to the ebuild.
_________________
"We must all hang together, or assuredly we shall all hang separately."
-Ben Franklin
Back to top
View user's profile Send private message
mb.Tab
n00b
n00b


Joined: 07 May 2006
Posts: 44
Location: /home/mb.Tab

PostPosted: Thu May 18, 2006 2:10 pm    Post subject: Reply with quote

Cool Thanks for it....will try it out later this day...:)....and report any issues !

mb.Tab
_________________
[center]~*It´s mb.Tab*~[/center]
Back to top
View user's profile Send private message
guid0
Guru
Guru


Joined: 06 Jul 2003
Posts: 308
Location: The Netherlands / Nederland

PostPosted: Sat Jul 01, 2006 7:58 pm    Post subject: Reply with quote

nice. now lets get it in portage :D
Back to top
View user's profile Send private message
t0nik
n00b
n00b


Joined: 11 Oct 2002
Posts: 55
Location: Moscow, Russia

PostPosted: Tue Jul 11, 2006 12:57 pm    Post subject: Reply with quote

I've made a ebuild for media-video/devede-2.1:
Code:
# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils

DESCRIPTION="DVD Video Creator"
HOMEPAGE="http://www.rastersoft.com/programas/devede.html"
SRC_URI="http://www.rastersoft.com/descargas/${PN}${PV/\.}.tar.bz2"

LICENSE="GPL"
SLOT="0"
KEYWORDS="~x86 ~amd64"
IUSE="nls doc"

RDEPEND=">=x11-libs/gtk+-2.4
        >=dev-lang/python-2.4
        dev-util/glade
        dev-python/pygtk
        media-video/mplayer
        media-video/dvdauthor
        media-video/vcdimager
        app-cdr/cdrtools"

DEPEND="${RDEPEND}"

S=${WORKDIR}/${PN}

src_install() {
    newbin ${S}/devede.py devede
    if use nls; then
        insinto /usr/share/locale/es/LC_MESSAGES
        newins ${S}/po/es.mo devede.mo
        insinto /usr/share/locale/gl/LC_MESSAGES
        newins ${S}/po/gl.mo devede.mo
    fi
    insinto /usr/share/applications
    doins ${S}/${PN}.desktop
    insinto /usr/share/pixmaps
    doins ${S}/${PN}.png
    insinto /usr/share/${PN}
    doins ${S}/${PN}.glade
    insinto /usr/share/${PN}
    doins ${S}/pixmaps/*
    if use doc; then
        insinto /usr/share/doc/${P}/html
        dohtml ${S}/docs/*
    fi
}

_________________
sorry my bad english :(
t0nik
Back to top
View user's profile Send private message
mb.Tab
n00b
n00b


Joined: 07 May 2006
Posts: 44
Location: /home/mb.Tab

PostPosted: Wed Jul 12, 2006 11:19 am    Post subject: Reply with quote

Hey, thanks for that ebuild. The prog seems to work so far, although I haven´t converted any file yet !

:)
_________________
[center]~*It´s mb.Tab*~[/center]
Back to top
View user's profile Send private message
crox
n00b
n00b


Joined: 26 Dec 2006
Posts: 3

PostPosted: Tue Dec 26, 2006 9:53 pm    Post subject: Reply with quote

I've adapted t0nik's ebuild for version 2.8:

Code:
# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils

DESCRIPTION="DVD Video Creator"
HOMEPAGE="http://www.rastersoft.com/programas/devede.html"
SRC_URI="http://www.rastersoft.com/descargas/${PN}${PV/\.}.tar.bz2"

LICENSE="GPL"
SLOT="0"
KEYWORDS="~x86 ~amd64"
IUSE="nls doc"

RDEPEND=">=x11-libs/gtk+-2.4
        >=dev-lang/python-2.4
        dev-util/glade
        dev-python/pygtk
        media-video/mplayer
        media-video/dvdauthor
        media-video/vcdimager
        app-cdr/cdrtools"

DEPEND="${RDEPEND}"

S=${WORKDIR}/${PN}${PV/\.}

src_install() {
    newbin ${S}/devede.py devede
    if use nls; then
        insinto /usr/share/locale/es/LC_MESSAGES
        newins ${S}/po/es.mo devede.mo
        insinto /usr/share/locale/gl/LC_MESSAGES
        newins ${S}/po/gl.mo devede.mo
    fi
    insinto /usr/share/applications
    doins ${S}/${PN}.desktop
    insinto /usr/share/pixmaps
    doins ${S}/${PN}.png
    insinto /usr/share/${PN}
    doins ${S}/${PN}.glade
    insinto /usr/share/${PN}
    doins ${S}/pixmaps/*
    insinto /usr/lib/${PN}
    doins ${S}/${PN}_*.py
    insinto /usr/share/${PN}
    doins ${S}/*.ttf
    if use doc; then
        insinto /usr/share/doc/${P}/html
        dohtml ${S}/docs/*
    fi
}

Back to top
View user's profile Send private message
mariourk
l33t
l33t


Joined: 11 Jul 2003
Posts: 807
Location: Urk, Netherlands

PostPosted: Fri Dec 29, 2006 7:32 pm    Post subject: Reply with quote

I'ma able to make an iso. But the subtitles I added are not on the DVD

Anyone knows why? :?
_________________
If there is one thing to learn from history, it's that we usualy don't learn anything from it, at all.
Back to top
View user's profile Send private message
Dr. Strangelove
Tux's lil' helper
Tux's lil' helper


Joined: 01 May 2006
Posts: 104
Location: Germania

PostPosted: Wed Feb 14, 2007 9:35 am    Post subject: Reply with quote

Thanks for sharing, guys!
Now version 2.11 is out, I've updated the ebuild as well.

media-video/devede/devede-2.11.ebuild
Code:
# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils

DESCRIPTION="DVD Video Creator"
HOMEPAGE="http://www.rastersoft.com/programas/devede.html"
SRC_URI="http://www.rastersoft.com/descargas/${PN}-${PV}.tar.bz2"

LICENSE="GPL"
SLOT="0"
KEYWORDS="~x86 ~amd64"
IUSE="nls doc"

RDEPEND=">=x11-libs/gtk+-2.4
        >=dev-lang/python-2.4
        dev-python/pygtk
        media-video/mplayer
        media-video/dvdauthor
        media-video/vcdimager
        app-cdr/cdrtools"

DEPEND="${RDEPEND}"

S=${WORKDIR}/${PN}-${PV}

src_install() {
    newbin ${S}/devede.py devede
    if use nls; then
        insinto /usr/share/locale/es/LC_MESSAGES
        newins ${S}/po/es.mo devede.mo
        insinto /usr/share/locale/gl/LC_MESSAGES
        newins ${S}/po/gl.mo devede.mo
        insinto /usr/share/locale/cs_CZ/LC_MESSAGES
        newins ${S}/po/cs_CZ.mo devede.mo
        insinto /usr/share/locale/de_DE/LC_MESSAGES
        newins ${S}/po/de_DE.mo devede.mo
        insinto /usr/share/locale/it/LC_MESSAGES
        newins ${S}/po/it.mo devede.mo
        insinto /usr/share/locale/nb_NO/LC_MESSAGES
        newins ${S}/po/nb_NO.mo devede.mo
        insinto /usr/share/locale/pt_BR/LC_MESSAGES
        newins ${S}/po/pt_BR.mo devede.mo
    fi
    insinto /usr/share/applications
    doins ${S}/${PN}.desktop
    insinto /usr/share/pixmaps
    doins ${S}/${PN}.png
    insinto /usr/share/${PN}
    doins ${S}/${PN}.glade
    insinto /usr/share/${PN}
    doins ${S}/pixmaps/*
    insinto /usr/lib/${PN}
    doins ${S}/${PN}_*.py
    insinto /usr/share/${PN}
    doins ${S}/*.ttf
    if use doc; then
        insinto /usr/share/doc/${P}/html
        dohtml ${S}/docs/*
    fi
}

pkg_postinst() {
        elog "You may change settings in ~/.devede, created after first run."
}



EDIT:
More translations available!
Added postinstall message.
EDIT2: removed dev-util/glade dependency because it seems not needed really
_________________
Gentoo Linux ~amd64, Kernel 3.6-rc5, Enermax Pro82+ 425W, AMD Athlon 64 X2 BE-2400, Infineon PC800 8GB, ASUS M2NPV-VM, MSI 8600GTS DualHead, SSD OCZ Vertex2 60GB, HDD Samsung Spinpoint F1 320GB HD322HJ, ODD BENQ-DW1640, DVB-S TechniSat SkyStar2
Back to top
View user's profile Send private message
mb.Tab
n00b
n00b


Joined: 07 May 2006
Posts: 44
Location: /home/mb.Tab

PostPosted: Thu Feb 15, 2007 12:42 pm    Post subject: Reply with quote

Thanks a lot for your work
_________________
[center]~*It´s mb.Tab*~[/center]
Back to top
View user's profile Send private message
Voyageur
Developer
Developer


Joined: 06 Mar 2005
Posts: 342
Location: Paris, France

PostPosted: Thu Feb 15, 2007 1:52 pm    Post subject: Reply with quote

Don't forget to add your ebuild version to the open bugreport

Also, a few notes/cleanups:
* "GPL" is not a valid license in portage (you must specify the version), use "GPL-2" here
* ${P} is shorter and cleaner than ${PN}-${PV} ;)
* the "S=..." line is redundant (this is the default one), you can remove it
* (will test it more thoroughly later) it works as well with cdrkit as with cdrtools, you can RDEPEND on
Code:
|| ( app-cdr/cdrtools app-cdr/cdrkit )


Hum... I wonder how well it copes with matroska files, I'll take a look tonight
_________________
Routinely breaking NX, GNUstep, net-ftp, miscellaneous (llvm, filezilla, rdesktop, chromium, ...) packages
Back to top
View user's profile Send private message
Dr. Strangelove
Tux's lil' helper
Tux's lil' helper


Joined: 01 May 2006
Posts: 104
Location: Germania

PostPosted: Sun Feb 18, 2007 3:25 pm    Post subject: Reply with quote

Voyageur,
many thanks for the helpful hints. It really strengthened my interest to gain an insight in making ebuilds well.
Now I have done quite a step and cleaned it up a bit. Of course the knowledge is borrowed by looking at other ebuilds.
The native language selection is now handled through the linguas variable. Also rearranged the order in src_install() to get rid of the many ${S}/*. Still not sure about the dropped glade dependency, but here it works fine without. Would be nice to know if you can use either cdrkit or cdrtools, please share your results.

media-video/devede/devede-2.11.ebuild
Code:
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils

DESCRIPTION="DVD Video Creator"
HOMEPAGE="http://www.rastersoft.com/programas/devede.html"
SRC_URI="http://www.rastersoft.com/descargas/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86 ~amd64"

LANGS="cs_CZ de_DE es gl it nb_NO pt_BR"
IUSE="doc nls"
    for i in ${LANGS}; do
        IUSE="${IUSE} linguas_${i}"
    done

RDEPEND=">=x11-libs/gtk+-2.4
        >=dev-lang/python-2.4
        dev-python/pygtk
        media-video/mplayer
        media-video/dvdauthor
        media-video/vcdimager
        app-cdr/cdrtools"

DEPEND="${RDEPEND}"

src_install() {
    newbin devede.py devede
    doicon ${PN}.png
    domenu ${PN}.desktop

    insinto /usr/share/${PN}
    doins ${PN}.glade
    insinto /usr/share/${PN}
    doins pixmaps/*
    insinto /usr/lib/${PN}
    doins ${PN}_*.py
    insinto /usr/share/${PN}
    doins *.ttf

    if use doc; then
        insinto /usr/share/doc/${P}/html
        dohtml ${S}/docs/*
    fi

    if use nls; then   
        cd po/
        for n in *.mo; do
            if use linguas_${n/.mo}; then
                insinto /usr/share/locale/${n/.mo}/LC_MESSAGES
                newins ${n} ${PN}.mo
            fi
        done
    fi
}

pkg_postinst() {
   elog "You may change settings in ~/.devede, created after first run."
}



With posting on bugzilla unfortunately I've no experience and no account at once, maybe some other nice guy could do that?

EDIT: The latest ebuild is now on bugzilla, view https://bugs.gentoo.org/show_bug.cgi?id=139986
_________________
Gentoo Linux ~amd64, Kernel 3.6-rc5, Enermax Pro82+ 425W, AMD Athlon 64 X2 BE-2400, Infineon PC800 8GB, ASUS M2NPV-VM, MSI 8600GTS DualHead, SSD OCZ Vertex2 60GB, HDD Samsung Spinpoint F1 320GB HD322HJ, ODD BENQ-DW1640, DVB-S TechniSat SkyStar2
Back to top
View user's profile Send private message
Voyageur
Developer
Developer


Joined: 06 Mar 2005
Posts: 342
Location: Paris, France

PostPosted: Mon Feb 26, 2007 10:14 pm    Post subject: Reply with quote

You're welcome! Reading ebuilds already in portage is also a favorite method of mine ;)

Also I made some ISOs with cdrkit installed, all went well (after all cdrkit is still a fork of cdrtools). There were talks about a virtual/cdrtools or something like that at some time, but for now it's manually one or the other (exclusive since they are blockers to each other)
_________________
Routinely breaking NX, GNUstep, net-ftp, miscellaneous (llvm, filezilla, rdesktop, chromium, ...) packages
Back to top
View user's profile Send private message
Dr. Strangelove
Tux's lil' helper
Tux's lil' helper


Joined: 01 May 2006
Posts: 104
Location: Germania

PostPosted: Wed Feb 28, 2007 2:27 pm    Post subject: Reply with quote

Version bump to 2.12! Changes are:
    * Added french translation. (and portuguese as well)
    * Fixed some issues with non-UTF8 systems

Voyageur wrote:
There were talks about a virtual/cdrtools or something like that at some time, but for now it's manually one or the other (exclusive since they are blockers to each other)

I've checked both the ebuilds of cdrkit and cdrtools, they are providing virtual/cdrtools.
So for now I've changed the dependency to virtual/cdrtools.

You may notice that the "Info" button still shows version 2.11, though it seems to be an oblivion in devede.glade.
The ebuild can be found on bugzilla: https://bugs.gentoo.org/show_bug.cgi?id=139986
_________________
Gentoo Linux ~amd64, Kernel 3.6-rc5, Enermax Pro82+ 425W, AMD Athlon 64 X2 BE-2400, Infineon PC800 8GB, ASUS M2NPV-VM, MSI 8600GTS DualHead, SSD OCZ Vertex2 60GB, HDD Samsung Spinpoint F1 320GB HD322HJ, ODD BENQ-DW1640, DVB-S TechniSat SkyStar2
Back to top
View user's profile Send private message
Dr. Strangelove
Tux's lil' helper
Tux's lil' helper


Joined: 01 May 2006
Posts: 104
Location: Germania

PostPosted: Tue Apr 17, 2007 5:58 pm    Post subject: Reply with quote

Version bump to 2.13! Changes are:
    * Added creation of MPEG4/DIVX files.
    * Added swedish and slovak translations.
    * Fixed some issues with translations (thanks to Marco de Freitas)

The updated ebuild can be found as #139986 at bugzilla.
_________________
Gentoo Linux ~amd64, Kernel 3.6-rc5, Enermax Pro82+ 425W, AMD Athlon 64 X2 BE-2400, Infineon PC800 8GB, ASUS M2NPV-VM, MSI 8600GTS DualHead, SSD OCZ Vertex2 60GB, HDD Samsung Spinpoint F1 320GB HD322HJ, ODD BENQ-DW1640, DVB-S TechniSat SkyStar2
Back to top
View user's profile Send private message
anz
Apprentice
Apprentice


Joined: 05 Feb 2003
Posts: 279
Location: Vienna

PostPosted: Thu Apr 26, 2007 10:31 am    Post subject: Reply with quote

Thanks alot, Dear labor_ratte,
the ebuild from the bugzilla link works on ~x86 and ~amd64!
(DeVeDe in combination with avidemux is great!)
_________________
Greetings from Vienna
Back to top
View user's profile Send private message
Dr. Strangelove
Tux's lil' helper
Tux's lil' helper


Joined: 01 May 2006
Posts: 104
Location: Germania

PostPosted: Tue May 01, 2007 6:36 pm    Post subject: Reply with quote

You're welcome, anz! :)
If anyone using this ebuild is experiencing some issues, i.e. missing or wrong dependencies, please let me know.
I've just changed the LINGUAS handling to more common variables.
_________________
Gentoo Linux ~amd64, Kernel 3.6-rc5, Enermax Pro82+ 425W, AMD Athlon 64 X2 BE-2400, Infineon PC800 8GB, ASUS M2NPV-VM, MSI 8600GTS DualHead, SSD OCZ Vertex2 60GB, HDD Samsung Spinpoint F1 320GB HD322HJ, ODD BENQ-DW1640, DVB-S TechniSat SkyStar2
Back to top
View user's profile Send private message
devsk
Advocate
Advocate


Joined: 24 Oct 2003
Posts: 2841
Location: Bay Area, CA

PostPosted: Sat May 26, 2007 11:10 pm    Post subject: Reply with quote

why is it not in portage as yet?
Back to top
View user's profile Send private message
Rainmaker
Veteran
Veteran


Joined: 12 Feb 2004
Posts: 1650
Location: /home/NL/ehv/

PostPosted: Sun May 27, 2007 1:07 am    Post subject: Reply with quote

devsk wrote:
why is it not in portage as yet?


From the bug report:

Quote:
Assigned To: Default Assignee for New Packages <maintainer-wanted@gentoo.org>


So there is no maintainer yet...
_________________
If you can't dazzle them with brilliance, baffle them with bullshit.
Back to top
View user's profile Send private message
Display posts from previous:   
Reply to topic    Gentoo Forums Forum Index Unsupported Software All times are GMT
Page 1 of 1

 
Jump to:  
You cannot post new topics in this forum
You cannot reply to topics in this forum
You cannot edit your posts in this forum
You cannot delete your posts in this forum
You cannot vote in polls in this forum