My first ebuild, keeps looking on the mirrorlist for the src

[kofrad]

I finally succeeded in creating a working ebuild, however there has been one problem trying to get it to work. When portage goes to download the source tarball, it looks for the package on the official gentoo mirrors - not the SRC_URI I provided in the ebuild. I was able to get it to properly build and install on my machine by manually downloading the source to /usr/portage/distfiles/

Can anyone help me figure out why this is happening?
What else might I need to do to get this ebuild ready to submit to the bugtracker for potential inclusion in the full tree?

On another note, I'm considering making a live ebuild to pull the source from git if I can get that figured out

Code: Select all

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils games

DESCRIPTION="Gravit is a free, visually stunning gravity simulator, where you can spend endless time experimenting with various configurations of simulated universes."
HOMEPAGE="http://gravit.slowchop.com/"
SRC_URI="http://gravit.slowchop.com/media/downloads/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64"
IUSE="lua png"

REDEPEND=">=media-libs/libsdl-1.2.6
	media-libs/sdl-image
	media-libs/sdl-ttf
	virtual/opengl
	virtual/glu
	lua? ( >=dev-lang/lua-5.1 )
	png? ( media-libs/libpng )"
DEPEND="${RDEPEND}"

pkg_setup() {
	games_pkg_setup
}

src_compile() {
	egamesconf \
		$(use_enable lua) \
		$(use_enable png)
	emake || die
}

src_install() {
	emake DESTDIR="${D}" install || die

	dodoc AUTHORS ChangeLog COPYING NEWS README || die

	prepgamesdirs
}

[Chiitoo]

Hies.

Really new to ebuilds myself, so I'm really not sure if this is what you're looking for, at all, but:

Code: Select all

RESTRICT="mirror"

It's from my currently best attempt on sort of writing one myself, as seen [post=6959132]here[/post].

[kofrad]

Hies.

Really new to ebuilds myself, so I'm really not sure if this is what you're looking for, at all, but:

Code: Select all

RESTRICT="mirror"

It's from my currently best attempt on sort of writing one myself, as seen [post=6959132]here[/post].

That was it! Thanks a bunch for the quick reply

[Hu]

Code: Select all

# $Header: $

No explicit EAPI?

Code: Select all

REDEPEND=">=media-libs/libsdl-1.2.6

Spelling error. Variable REDEPEND is not standard. You probably meant RDEPEND.

Code: Select all

pkg_setup() {
	games_pkg_setup
}

You can probably omit this, in which case it will default to the corresponding function from an eclass that defined pkg_setup.

Code: Select all

src_compile() {
	egamesconf \
		$(use_enable lua) \
		$(use_enable png)

Configuration is better done in src_configure, though you need to use a higher EAPI to have that function.

[kofrad]

Code: Select all

# $Header: $

No explicit EAPI?

Code: Select all

REDEPEND=">=media-libs/libsdl-1.2.6

Spelling error. Variable REDEPEND is not standard. You probably meant RDEPEND.

Code: Select all

src_compile() {
	egamesconf \
		$(use_enable lua) \
		$(use_enable png)

Configuration is better done in src_configure, though you need to use a higher EAPI to have that function.

Thanks for pointing those things out. I'm reading through some more documentation of ebuilds and am double checking everything once again. Looks like I'll be fine with EAPI="2" for right now to use src_configure().

Code: Select all

pkg_setup() {
	games_pkg_setup
}

You can probably omit this, in which case it will default to the corresponding function from an eclass that defined pkg_setup.

From the documentation I read regarding the games eclass, I thought that would be the necessary for making sure the proper directories and permissions are created for running games.

After taking a second look, it seems like the eclass will override the default behavior and call whatever is needed by the games eclass, correct?

[kofrad]

Here is my revised ebuild, if anyone can look this over for any potential problems, it would be greatly appreciated. If all is well I will work on getting things like the ChangeLog together to submit onto the bug tracker for possible inclusion into the portage tree. Thanks everyone for all your help!

Code: Select all

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="2"

inherit eutils games

RESTRICT="mirror"
DESCRIPTION="Gravit is a free, visually stunning gravity simulator, where you can spend endless time experimenting with various configurations of simulated universes."
HOMEPAGE="http://gravit.slowchop.com/"
SRC_URI="http://gravit.slowchop.com/media/downloads/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64"
IUSE="lua png"

RDEPEND=">=media-libs/libsdl-1.2.6
	media-libs/sdl-image
	media-libs/sdl-ttf
	virtual/opengl
	virtual/glu
	lua? ( >=dev-lang/lua-5.1 )
	png? ( media-libs/libpng )"
DEPEND="${RDEPEND}"

pkg_setup() {
	games_pkg_setup
}

src_configure() {
	if [[ -x ${ECONF_SOURCE:-.}/configure ]]; then
		egamesconf \
			$(use_enable lua) \
			$(use_enable png)
	fi
}

src_compile() {
	if [ -f Makefile ]; then
		emake || die "emake failed"
	fi
}

src_install() {
	emake DESTDIR="${D}" install || die "Install failed"

	dodoc AUTHORS ChangeLog NEWS README || die
	doicon data/gravit.png

	make_desktop_entry ${PN} Gravit /usr/share/pixmaps/${PN}.png

	prepgamesdirs
}

[Hu]

Testing for the presence of configure and Makefile is useful in the generic functions that ebuilds inherit, so that the ebuild does not need to override the function if the file is missing. However, for an ebuild where you control the function and know the upstream tarball, you know whether configure and Makefile exist. Therefore, there is no point in testing for them. If they exist now, assume they will continue to exist and remove the test. If they do not exist now, then the test is guaranteed to be false, so remove it and the code it guards.

[kofrad]

Thanks for the response, I had included it kind of as a sanity-check. After thinking about it though, I'm sure the standard ebuild functions include any that might be needed. Thanks for clarifying that for me.