Gentoo Forums
Gentoo Forums
Gentoo Forums
Quick Search: in
[overlay] games-strategy/0ad
View unanswered posts
View posts from last 24 hours

 
Reply to topic    Gentoo Forums Forum Index Unsupported Software
View previous topic :: View next topic  
Author Message
Navar
Apprentice
Apprentice


Joined: 20 Aug 2012
Posts: 252

PostPosted: Mon Apr 28, 2014 4:21 am    Post subject: [overlay] games-strategy/0ad Reply with quote

An updated ebuild on the game 0ad (see for details) for your local overlays:

0ad-99999.ebuild file:

Code:

# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $
# This ebuild came originally from an earlier hasufell overlay, 4-27-2014 modified by Navar

EAPI=5

WX_GTK_VER="2.8"

inherit eutils subversion wxwidgets games

MY_PV="r${PV%_*}-alpha"
MY_P=${PN}-${MY_PV}

DESCRIPTION="A free, real-time strategy game"
HOMEPAGE="http://wildfiregames.com/0ad/"
ESVN_REPO_URI="http://svn.wildfiregames.com/public/ps/trunk"

LICENSE="GPL-2+ CC-BY-SA-4.0"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="+audio +editor +pch test +nvtt lobby miniupnp"

RDEPEND="
        dev-lang/spidermonkey:24
        dev-libs/boost
        dev-libs/libxml2
        !games-strategy/0ad-data
        media-libs/libpng:0
        media-libs/libsdl[X,opengl,video]
        net-libs/enet:1.3
        net-misc/curl
        sys-libs/zlib
        virtual/jpeg
        virtual/opengl
        x11-libs/libX11
        audio? ( media-libs/libogg
                media-libs/libvorbis
                media-libs/openal )
        editor? ( x11-libs/wxGTK:${WX_GTK_VER}[X,opengl] )
        nvtt? ( media-gfx/nvidia-texture-tools )
        lobby? ( net-libs/gloox )
        miniupnp? ( net-libs/miniupnpc )
        "
DEPEND="${RDEPEND}
        virtual/pkgconfig
        test? ( dev-lang/perl )"

S=${WORKDIR}/trunk

pkg_setup() {
        games_pkg_setup

        if ! use pch ; then
                eerror "pch useflag is potentially broken"
                eerror "see http://trac.wildfiregames.com/ticket/1313"
        fi
}

src_unpack() {
        subversion_src_unpack
}

src_configure() {
        cd build/workspaces || die

        ./update-workspaces.sh \
                --with-system-enet \
                --with-system-mozjs24 \
                $(usex pch "" "--without-pch") \
                $(usex test "" "--without-tests") \
                $(usex audio "" "--without-audio") \
                $(usex nvtt "--with-system-nvtt" "--without-nvtt") \
                $(usex lobby "" "--without-lobby") \
                $(usex miniupnp "--with-system-miniupnpc" "--without-miniupnpc") \
                $(usex editor "--enable-atlas" "--disable-atlas") \
                --bindir="${GAMES_BINDIR}" \
                --libdir="$(games_get_libdir)"/${PN} \
                --datadir="${GAMES_DATADIR}"/${PN}

}

src_compile() {
        emake -C build/workspaces/gcc verbose=1 || die
}

src_test() {
        cd binaries/system || die
        ./test || die "test phase failed"
}

src_install() {
        # data
        insinto "${GAMES_DATADIR}"/${PN}
        doins -r binaries/data/* || die

        # bin
        dogamesbin binaries/system/pyrogenesis || die

        # libs
        exeinto "$(games_get_libdir)"/${PN}
        doexe binaries/system/libCollada.so || die
        if use editor ; then
                doexe binaries/system/libAtlasUI.so || die
        fi

        # other
        dodoc binaries/system/readme.txt
        doicon build/resources/${PN}.png
        games_make_wrapper ${PN} "${GAMES_BINDIR}/pyrogenesis"
        make_desktop_entry ${PN}

        # permissions
        prepgamesdirs
}


Manifest file:

Code:

EBUILD 0ad-99999.ebuild 2568 SHA256 2bdf3281b0c8db290a1b21bc4357592fa2f1fdeff6ef40f3151714effb4e167e SHA512 b825d29ba67942f1a04167d298e21354dd5b6a431825ddff69664644502433cf03ce3306361664a373a7bc7f5775cbdf53b6c85b8c693558c077c1f507804e49 WHIRLPOOL fafba8ef4d95dbc9fd03e77c87d641f04b1b35af0e3b2b09fd306c15e9135e179a3894c96e83186a4a6ca56b9c094ee0e100ca56c0817eefe611a7002d52bb71
MISC metadata.xml 660 SHA256 b9e716fe98cd7ee352fd338b04ac14ef4bffd86432c842cba7739f21c7957e0c SHA512 5776e29d832ce25c914e507f6b6d6f55db9661866d246e7768f5ca7d14d53d791ae02f6b4532539b0049a06261f35386d526dc16f169897a3b00856c6ca87857 WHIRLPOOL 680abe4f85568806e63bb6f92aa3e2c89c986670814dcbebe0abbce5d5456128089fb8e4a93d1801411a55a253612804711151e92158b6e53b25d7d4c76007b3


metadata.xml file:

Code:

<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
   <maintainer>
      <email>na@na.org</email>
      <name>navar @ forums.gentoo.org</name>
   </maintainer>
   <use>
      <flag name='audio'>Add audio support via OpenAL/Ogg/Vorbis</flag>
      <flag name='editor'>Include Atlas scenario editor projects</flag>
      <flag name='nvtt'>Enable use of system nvidia-texture-tools library</flag>
      <flag name='lobby'>Add support for in-game lobby via gloox</flag>
      <flag name='miniupnp'>Enable use of system mini-upnp for automatic port forwarding</flag>
   </use>
</pkgmetadata>


TODO: SVN -> GIT migration
Back to top
View user's profile Send private message
Display posts from previous:   
Reply to topic    Gentoo Forums Forum Index Unsupported Software All times are GMT
Page 1 of 1

 
Jump to:  
You cannot post new topics in this forum
You cannot reply to topics in this forum
You cannot edit your posts in this forum
You cannot delete your posts in this forum
You cannot vote in polls in this forum