Gentoo Forums
Gentoo Forums
Gentoo Forums
Quick Search: in
stasmodels-9999 development ebuild
View unanswered posts
View posts from last 24 hours

 
Reply to topic    Gentoo Forums Forum Index Unsupported Software
View previous topic :: View next topic  
Author Message
luciano
Tux's lil' helper
Tux's lil' helper


Joined: 18 Nov 2004
Posts: 93

PostPosted: Tue Apr 09, 2013 2:02 pm    Post subject: stasmodels-9999 development ebuild Reply with quote

Hi, I'd like to share a new development ebuild for statsmodels, as the latest stable one is lacking a lot of features from the development branch and some of the API has changed considerably. I based it [the ebuild] on the 0.4x version in the official repo. Hope it will be useful to somebody:

Code:

# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=5
PYTHON_COMPAT=( python{2_6,2_7} )

inherit git-2 distutils-r1 virtualx

MYPN="${PN/scikits_/}"
MYP="${MYPN}-${PV}"

DESCRIPTION="Statsmodels Unstable"
HOMEPAGE="http://statsmodels.sourceforge.net"
SRC_URI=""
EGIT_REPO_URI="git://github.com/${MYPN}/${MYPN}.git"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64"
IUSE="doc examples test"

RDEPEND="
   dev-python/pandas[${PYTHON_USEDEP}]
   sci-libs/scikits[${PYTHON_USEDEP}]
   sci-libs/scipy[${PYTHON_USEDEP}]
   dev-python/patsy[${PYTHON_USEDEP}]
   examples? ( dev-python/matplotlib[${PYTHON_USEDEP}] )"
DEPEND="
   >=dev-python/cython-0.15.1[${PYTHON_USEDEP}]
   dev-python/pandas[${PYTHON_USEDEP}]
   dev-python/setuptools[${PYTHON_USEDEP}]
   sci-libs/scipy[${PYTHON_USEDEP}]
   doc? (
      dev-python/matplotlib[${PYTHON_USEDEP}]
      dev-python/sphinx[${PYTHON_USEDEP}]
      >=dev-python/ipython-0.12 )
   test? ( dev-python/nose[${PYTHON_USEDEP}] )"

S="${WORKDIR}/${MYP}"

python_compile_all() {
   use doc && esetup.py build_sphinx
}

python_test() {
   cd "${BUILD_DIR}" || die
   VIRTUALX_COMMAND="nosetests"
   virtualmake --verbosity=3
}

python_install_all() {
   find "${S}" -name \*LICENSE.txt -delete
   use doc && HTML_DOCS=( build/sphinx/html/* )
   if use examples; then
      insinto /usr/share/doc/${PF}
      doins -r examples
   fi
   distutils-r1_python_install_all
}

python_install() {
   distutils-r1_python_install
   #rm "${D}"$(python_get_sitedir)/scikits/__init__.py || die
}


And you'll also need patsy, a new dependency (goes under dev-python/patsy):

Code:

# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=5
PYTHON_COMPAT=( python{2_6,2_7} )

inherit git-2 distutils-r1 virtualx

DESCRIPTION="Patsy unstable"
HOMEPAGE="http://patsy.readthedocs.org/en/latest/overview.html"
SRC_URI=""
EGIT_REPO_URI="git://github.com/pydata/patsy.git"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64"
IUSE=""

DEPEND=">=dev-python/cython-0.15.1[${PYTHON_USEDEP}]
   dev-python/numpy[${PYTHON_USEDEP}]"
RDEPEND="${DEPEND}"


They build and appear to be usable, but I've not tested them extensively. I'm not an expert in packaging so I can't really volunteer to maintain it or get it added to the main repo. But I'm sharing it as I couldn't find it for any of the overlays.
Back to top
View user's profile Send private message
Display posts from previous:   
Reply to topic    Gentoo Forums Forum Index Unsupported Software All times are GMT
Page 1 of 1

 
Jump to:  
You cannot post new topics in this forum
You cannot reply to topics in this forum
You cannot edit your posts in this forum
You cannot delete your posts in this forum
You cannot vote in polls in this forum